ABAP Keyword Documentation →  ABAP - Reference →  Creating Objects →  CREATE DATA 

CREATE DATA dref

Short Reference

Other versions: 7.31 | 7.40 | 7.54

Syntax

CREATE DATA dref [area_handle]. 

Effect

If neither of the TYPE or LIKE additions is specified, the dref data reference variable must be fully typed. The data object is then created with the static data type of the data reference variable.

Example

Creation of an internal table and a data object of type i. The data objects are created directly before they are used and are then initialized by the reference variables and passed to the garbage collector. The data objects are accessed by dereferencing the data references.

TYPES t_itab TYPE TABLE OF i WITH NON-UNIQUE KEY table_line. 

DATA: tab_ref TYPE REF TO t_itab, 
      i_ref   TYPE REF TO i. 

DO 10 TIMES. 
  IF tab_ref IS INITIAL. 
    CREATE DATA tab_ref. 
  ENDIF. 
  APPEND sy-index TO tab_ref->*. 
ENDDO. 

IF tab_ref IS NOT INITIAL. 
  IF i_ref IS INITIAL. 
    CREATE DATA i_ref. 
  ENDIF. 
  LOOP AT tab_ref->* INTO i_ref->*. 
    WRITE / i_ref->*. 
  ENDLOOP. 
ENDIF. 

CLEAR: tab_ref, i_ref.