Skip to content

ABAP Keyword Documentation →  ABAP - Reference →  User Dialogs →  Selection Screens →  Create Selection Screens →  SELECTION-SCREEN →  SELECTION-SCREEN - screen_elements 

SELECTION-SCREEN - COMMENT

Short Reference

Other versions: 7.31 | 7.40 | 7.54

Syntax


SELECTION-SCREEN COMMENT [/]pos|POS_LOW|POS_HIGH 

                        {text|{[text] FOR FIELD sel}} 

                         [VISIBLE LENGTH vlen] 

              
          [MODIF ID modid] 

              
          [ldb_additions].

Extras

1. ... [/]pos|POS_LOW|POS_HIGH

2. ... FOR FIELD sel

3. ... VISIBLE LENGTH vlen

Effect

This statement creates an output field on the current selection screen and enters the content of text in this field. In text, either the name of the text symbol of the program can be specified in the form text-idf, where idf is the three-character ID for the text symbol, or a user-defined name with a maximum of eight characters. If a user-defined name is entered, the runtime environment generates a global variable of the same name with type c and length 83. If the specified text symbol is not found, no text is entered in the output field. The MODIF ID addition assigns the output field to the modification groupmodid.

The ldb_additions can only be used in the selection include of a logical database.

Addition 1

... [/]pos|POS_LOW|POS_HIGH

Effect

The position of the output field must be specified with this addition. The syntax and the meaning are the same as when generating horizontal lines. In this case, len defines the length of the output field in the dynpro of the selection screen. If an output field extends beyond position 83 or sticks out of a block with a frame, the visible length is shortened accordingly and the content is displayed in the visible length.

Addition 2

... FOR FIELD sel

Effect

If the addition FOR FIELD is used, the output field is associated with a parameter or sel selection criterion of the same program defined using PARAMETERS or SELECT-OPTIONS. The name sel must be specified directly. When this association is made, the field help or input help for sel is displayed when the user selects the output field using the function keys F1 and F4. It also means that the output field is assigned to the same modification group. The output field is also hidden if sel is made invisible using a variant. If FOR FIELD is specified, text does not have to be specified. The output field is then filled either with the specified name sel, or, if it exists in the current text pool, with the corresponding selection text.


Notes

  • The addition FOR FIELD causes the output field output field to behave in exactly the same way as the output fields generated automatically by PARAMETERS or SELECT-OPTIONS in response to parameters or selection criteria. Automatically generated fields are not displayed in a line if multiple elements are included in the output, and can thus be replaced by associated user-defined output fields.
  • The FOR FIELD addition is also important for creating accessible selection screens, since it assigns an accessible descriptor to an input field.

Addition 3

... VISIBLE LENGTH vlen

Effect

The addition VISIBLE LENGTH defines the visible length vlen of the output field. vlen must be specified directly as a positive integer. If vlen is greater than len, the visible length is set to len. If vlen is less than len, the output field is displayed in the length of vlen with movable content and a tooltip of the whole content.


Example

Output fields, horizontal lines, and empty lines on the standard selection screen of an executable program. The first output field is highlighted in the display.

SELECTION-SCREEN COMMENT /1(50) comm1 MODIF ID mg1. 
SELECTION-SCREEN ULINE. 
SELECTION-SCREEN SKIP. 

SELECTION-SCREEN COMMENT /1(30) comm2. 
SELECTION-SCREEN ULINE /1(50). 
PARAMETERS: r1 RADIOBUTTON GROUP rad1, 
            r2 RADIOBUTTON GROUP rad1, 
            r3 RADIOBUTTON GROUP rad1. 
SELECTION-SCREEN ULINE /1(50). 

DATA screen_wa TYPE screen. 

AT SELECTION-SCREEN OUTPUT. 
  comm1 = 'Selection Screen'. 
  comm2 = 'Select one'. 
  LOOP AT SCREEN INTO screen_wa. 
    IF screen_wa-group1 = 'MG1'. 
       screen_wa-intensified = '1'. 
      MODIFY SCREEN FROM screen_wa. 
    ENDIF. 
  ENDLOOP.