Skip to content

ABAP Keyword Documentation →  ABAP - Reference →  program editing →  Dynamic Program Editing →  Source Code 

SYNTAX-CHECK

Short Reference

Other versions: 7.31 | 7.40 | 7.54

Syntax


SYNTAX-CHECK FOR itab MESSAGE mess LINE lin WORD wrd 

                [PROGRAM prog] [DIRECTORY ENTRY dir] 

                 [WITH CURRENT SWITCHSTATES] 

              
                 
    [error_handling].

Extras

1. ... PROGRAM prog

2. ... DIRECTORY ENTRY dir

3. ... WITH CURRENT SWITCHSTATES

Effect

This statement executes a syntax check on the content of the internal table itab. The internal table itab must be a standard table without secondary table keys with a character-like row type.

If the internal table does not contain syntactically correct ABAP source code, then:

  • The error message of the first syntax error is assigned to variable mess. mess must be a character-like data object.
  • The line number of the first syntax error, with reference to the program in which it occurs (either the source code in itab or an integrated include program included there) is assigned to the variable lin. lin expects the data type i.
  • The first token with errors is assigned to the variable wrd. wrd must be a character-like data object.

The additions PROGRAM and DIRECTORY ENTRY are used to set the attributes for the syntax check. The WITH CURRENT SWITCHSTATES addition specifies which switch configuration is used for the syntax check. The other error_handling additions can be used to identify other attributes of the first syntax error.

System Fields

sy-subrc Meaning
0 The internal table itab contains a syntactically correct ABAP program.
4 The internal table itab does not contain a syntactically correct ABAP program.
8 Other errors occurred, such as a runtime error during the syntax check.

If a runtime error occurs during the syntax check (sy-subrc has the value 8), a database rollback is executed in the usual manner.


Note

It is not required to execute the SYNTAX-CHECK statement directly before GENERATE SUBROUTINE POOL or GENERATE REPORT, because the syntax check is always performed when these statements are executed.

Addition 1

... PROGRAM prog

Addition 2

... DIRECTORY ENTRY dir

Effect

These additions are used to specify the program attributes used for the syntax check.

  • The PROGRAM addition is used to specify in prog the name of an ABAP program whose program attributes are to be used for the syntax check. prog must be a character-like data object, whose content is not case-sensitive. If the specified program is not found, the standard attributes specified below are used.
  • After the DIRECTORY ENTRY addition, you must specify a data object dir, whose data type corresponds to the structure of database table TRDIR from ABAP Dictionary. In the components of this structure, you can specify the required program attributes. Invalid values are replaced implicitly by internally defined standard values.

In non-Unicode programs, you should, and in Unicode programs, you must specify one of these two additions. If neither PROGRAM nor DIRECTORY ENTRY is specified, the system uses executable program as the default program type. General default values are then assigned to the the remaining program attributes. If both additions PROGRAM and DIRECTORY ENTRY are specified, the program attributes are determined by the structure dir.


Notes

  • We recommend the use of addition PROGRAM, because the components of structure dir and their valid values can be interpreted within the system only. If addition DIRECTORY ENTRY is nevertheless used in application programs, the content of structure dir should be set by reading the appropriate entry from database table TRDIR and by modifying only individual components as required.
  • Important program attributes for the syntax check are, for example, the program type and whether the program is a Unicode program.


Example

Syntax check for source code in itab. By reading the attributes of the current program from the database TRDIR into the structure dir, these can be used after DIRECTORY ENTRY. When the dir-uccheck component is set, the first syntax check is executed in the same way as for non-Unicode programs and the second as for Unicode programs. The first syntax check does not find an error in a non-Unicode system and detects the error when the program is not Unicode-enabled. The second syntax check always identifies the error when the BYTE or CHARACTER MODE addition is missing from the DESCRIBE statement.

DATA: itab TYPE STANDARD TABLE OF string, 
      mess TYPE string, 
      lin  TYPE i, 
      wrd  TYPE string, 
      dir  TYPE trdir. 

APPEND 'PROGRAM test.'                 TO itab. 
APPEND 'DATA dat TYPE d.'               TO itab. 
APPEND 'DATA len TYPE i.'               TO itab. 
APPEND 'DESCRIBE FIELD dat LENGTH len.' TO itab. 

SELECT SINGLE * 
       FROM trdir 
       INTO dir 
       WHERE name = sy-repid. 

dir-uccheck = ' '. 

SYNTAX-CHECK FOR itab MESSAGE mess LINE lin WORD wrd 
             DIRECTORY ENTRY dir. 

IF sy-subrc = 4. 
  MESSAGE mess TYPE 'I'. 
ENDIF. 

dir-uccheck = 'X'. 

SYNTAX-CHECK FOR itab MESSAGE mess LINE lin WORD wrd 
             DIRECTORY ENTRY dir. 

IF sy-subrc = 4. 
  MESSAGE mess TYPE 'I'. 
ENDIF.

Addition 3

... WITH CURRENT SWITCHSTATES

Effect

This addition causes the syntax check to use the switch configuration of the Switch Framework, in the state it had when the current transaction was called. Without the addition, the switch configuration valid when the statement is executed is used.

  • This addition causes the syntax check to run with the same switch states from Switch Framework as were used when the statement GENERATE SUBROUTINE POOL was executed.
  • Without the addition, the syntax check is performed in the same way as for every regular compilation of ABAP programs.

Continue

SYNTAX-CHECK - error_handling

SYNTAX-CHECK - Internal Additions