ABAP Keyword Documentation →  ABAP − Reference →  Data Interfaces and Communication Interfaces →  ABAP and XML →  Class Libraries for XML →  iXML Library →  iXML Library, Examples 

iXML Library, Iterator for Attributes

Accesses the attributes of an element list in DOM using an iterator.

Other versions: 7.31 | 7.40 | 7.54

Source Code

REPORT demo_ixml_attribute_iterator.

CLASS ixml_demo DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS main.
ENDCLASS.

CLASS ixml_demo IMPLEMENTATION.
  METHOD main.
    DATA(ixml)           = cl_ixml=>create( ).
    DATA(stream_factory) = ixml->create_stream_factory( ).

    DATA(istream)        = stream_factory->create_istream_string(
      `<texts>`                                       &&
      `  <text1 format="bold"   level="1">aaa</text1>` &&
      `  <text2 format="italic" level="2">bbb</text2>` &&
      `  <text3 format="arial"  level="3">ccc</text3>` &&
      `</texts>` ).

    DATA(document)       = ixml->create_document( ).
    DATA(parser)         = ixml->create_parser(
                             stream_factory = stream_factory
                            istream        = istream
                            document       = document ).

    DATA(rc) = parser->parse( ).

    IF rc <> ixml_mr_parser_ok.
      ... "Error handling
      RETURN.
    ENDIF.

    DATA(element) = document->get_root_element( ).
    DATA(child) = element->get_first_child( ).
    DATA(attributes) = child->get_attributes( ).
    DATA(iterator) = attributes->create_iterator( ).

    DO.
      DATA(attribute) = iterator->get_next( ).
      IF attribute IS INITIAL.
        EXIT.
      ENDIF.
      cl_demo_output=>write_text( |{ attribute->get_name( ) } | &&
                                 |{ attribute->get_value( ) }| ).
    ENDDO.

    cl_demo_output=>display( ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  ixml_demo=>main( ).

Description

XML data is first transformed to an input stream object and the object is then imported into a DOM object using a parser object. If parsed successfully, an iterator is created for the attributes of the first subnode of the root node and used for iterations.