ABAP Keyword Documentation →  ABAP − Reference →  Processing Internal Data →  Character String and Byte String Processing →  Statements for Character String and Byte String Processing →  WRITE - TO →  WRITE - Cutoff Behavior 

WRITE TO, Cutoff Behavior

This example demonstrates the cutoff behavior of the statement WRITE TO for all elementary data types.

Other versions: 7.31 | 7.40 | 7.54

Source Code

    DATA: dref TYPE REF TO data,
          len TYPE i,
          name TYPE string.

    FIELD-SYMBOLS <output> TYPE data.

    len = length.
    IF len < 1 OR len > 40.
      WRITE 'Length must be between 1 and 40!' COLOR COL_TOTAL.
      RETURN.
    ENDIF.

    setup( ).
    create_data( ).

    CREATE DATA dref TYPE c LENGTH len.
    ASSIGN dref->* TO <output>.
    LOOP AT names INTO name.
      TRY.
          CASE name.
            WHEN 't'.
              WRITE t TO <output> ENVIRONMENT TIME FORMAT.
            WHEN 'TIMESTAMP'.
              WRITE timestamp TO <output> TIME ZONE sy-zonlo.
            WHEN 'TIMESTAMPL'.
              WRITE timestampl TO <output> TIME ZONE sy-zonlo.
            WHEN OTHERS.
              WRITE (name) TO <output>.
          ENDCASE.
          display( name   = name len = len
                   output = <output> ).
        CATCH cx_root.
          display( name = name
                   len  = len output = '!' ).
      ENDTRY.
    ENDLOOP.

    teardown( ).

Description

The class demo contains an attribute for every predefined ABAP type and for time stamps in packed numbers. These attributes are filled with example values and assigned to a data object by WRITE TO. The length of this data object can be chosen on the selection screen.

The country-specific formats for numbers, dates, and times set by SET COUNTRY can also be specified on the selection screen. This example demonstrates these formats as well.

The output list shows the result of the formatting for each data type. If an exception is raised, the character "!" is highlighted in a different color.